WIKI ADO

Accueil > ArmA3 > Edition de missions > Afficher l'équipage d'un véhicule

Afficher l'équipage d'un véhicule

- Publié le 14 Septembre 2013 à 16h12 - Modifié le 30 Novembre 2013 à 21h12
Il est parfois pratique de pouvoir, en un coup d’œil, savoir qui est dans votre véhicule. Avec ce script, chaque joueur sera affiché dans une infobulle lorsque vous serez dans un véhicule. Pratique et léger!

equipages.sqf
if (!local player) exitWith {};

while {true} do {

        waitUntil {vehicle player != player};

        _equipages = (crew vehicle player);
        _nbEquipages = count _equipages;

        _type = "";
        _msg = "";
        _txt = "";
        _entete = parseText format["<t color='#FFFFCC'>  %1</t>",localize "STR_M04t71"];
        _separateur = parseText "<br /><br />";
        _vehicule = parseText format["<t size='2.2'><img image='%1'/></t>",getText (configFile >> "CfgVehicles" >> format["%1", typeOf (vehicle player)] >> "picture")];

        _tab = [_vehicule,_entete,_separateur];

        _i = 0;
        while {_i < _nbEquipages} do
        {
                _unite = (_equipages select _i);
                _name = name _unite;
                if(_name == "Error: No unit") then {_name = "?"};
                _type = parseText "<t align='left'><img image='a3\ui_f\data\IGUI\Cfg\Actions\getincargo_ca.paa'/></t>";
                if(_unite == driver vehicle _unite) then {_type = parseText "<t align='left'><img image='a3\ui_f\data\IGUI\Cfg\Actions\getindriver_ca.paa'/></t>"};
                if(_unite == gunner vehicle _unite) then {_type = parseText "<t align='left'><img image='a3\ui_f\data\IGUI\Cfg\Actions\getingunner_ca.paa'/></t>"};
                if(_unite == commander vehicle _unite) then {_type = parseText "<t align='left'><img image='a3\ui_f\data\IGUI\Cfg\Actions\getincommander_ca.paa'/></t>"};
                _tab = _tab + [_type];
                _msg = parseText format["<t color='#FFFFFF'>   %1</t><br /></t>",_name];
                _tab = _tab + [_msg];
                sleep 0.1;
                _i=_i+1;
        };

        _txt = composeText _tab;
        hintsilent _txt;
       
        sleep 2;
        if (vehicle player == player) then {hintsilent "";};
};

if (true) exitWith {};

Terminez en inscrivant dans votre init.sqf :
execVM "equipages.sqf";
Envoyé par Oden